mirror of
https://github.com/bitsycore/skiko.git
synced 2026-10-05 14:37:26 +00:00
Shagen Ogandzhanian
3a45780645
This PR updates SkikoJsSample (which is renamed to SkikoWebSample) in following aspects: - By default sample built against release version so that user can check the sample without local build at all - When build against local skiko, `skiko.version` parameter is ignored - Sample code commonized and prepared for future introduction of common web source sets in Kotlin 2.2.20
54 lines
1.9 KiB
Kotlin
54 lines
1.9 KiB
Kotlin
pluginManagement {
|
|
repositories {
|
|
mavenCentral()
|
|
gradlePluginPortal()
|
|
google()
|
|
maven("https://maven.pkg.jetbrains.space/kotlin/p/kotlin/dev")
|
|
}
|
|
|
|
plugins {
|
|
val kotlinVersion = extra["kotlin.version"] as String
|
|
kotlin("jvm").version(kotlinVersion)
|
|
kotlin("multiplatform").version(kotlinVersion)
|
|
}
|
|
}
|
|
|
|
// Define version catalog programmatically so we can read versions from gradle.properties
|
|
// This overrides the automatic import of gradle/libs.versions.toml for the "libs" catalog.
|
|
dependencyResolutionManagement {
|
|
versionCatalogs {
|
|
create("libs") {
|
|
version("skiko", providers.gradleProperty("skiko.version").get())
|
|
library("skiko", "org.jetbrains.skiko", "skiko").versionRef("skiko")
|
|
library("skiko-wasm-runtime", "org.jetbrains.skiko", "skiko-js-wasm-runtime").versionRef("skiko")
|
|
|
|
val osName = System.getProperty("os.name")
|
|
val hostOs = when {
|
|
osName == "Mac OS X" -> "macos"
|
|
osName.startsWith("Win") -> "windows"
|
|
osName.startsWith("Linux") -> "linux"
|
|
else -> error("Unsupported OS: $osName")
|
|
}
|
|
|
|
val osArch = System.getProperty("os.arch")
|
|
var hostArch = when (osArch) {
|
|
"x86_64", "amd64" -> "x64"
|
|
"aarch64" -> "arm64"
|
|
else -> error("Unsupported arch: $osArch")
|
|
}
|
|
|
|
library("skiko-awt-runtime", "org.jetbrains.skiko", "skiko-awt-runtime-$hostOs-$hostArch").versionRef("skiko")
|
|
}
|
|
}
|
|
}
|
|
|
|
rootProject.name = "SkiaMultiplatformSample"
|
|
|
|
if (extra.properties.getOrDefault("skiko.composite.build", "") == "1") {
|
|
includeBuild("../../skiko") {
|
|
dependencySubstitution {
|
|
substitute(module("org.jetbrains.skiko:skiko")).using(project(":"))
|
|
}
|
|
}
|
|
}
|