mirror of
https://github.com/bitsycore/skiko.git
synced 2026-10-05 14:37:26 +00:00
Shagen Ogandzhanian
3a45780645
This PR updates SkikoJsSample (which is renamed to SkikoWebSample) in following aspects: - By default sample built against release version so that user can check the sample without local build at all - When build against local skiko, `skiko.version` parameter is ignored - Sample code commonized and prepared for future introduction of common web source sets in Kotlin 2.2.20
37 lines
1.1 KiB
Kotlin
37 lines
1.1 KiB
Kotlin
pluginManagement {
|
|
repositories {
|
|
mavenLocal()
|
|
mavenCentral()
|
|
gradlePluginPortal()
|
|
maven {
|
|
url = uri("https://dl.bintray.com/kotlin/kotlin-eap")
|
|
}
|
|
}
|
|
plugins {
|
|
val kotlinVersion = extra["kotlin.version"] as String
|
|
kotlin("multiplatform").version(kotlinVersion)
|
|
}
|
|
}
|
|
|
|
// Define version catalog programmatically so we can read versions from gradle.properties
|
|
// This overrides the automatic import of gradle/libs.versions.toml for the "libs" catalog.
|
|
dependencyResolutionManagement {
|
|
versionCatalogs {
|
|
create("libs") {
|
|
version("skiko", providers.gradleProperty("skiko.version").get())
|
|
library("skiko", "org.jetbrains.skiko", "skiko").versionRef("skiko")
|
|
library("skiko-wasm-runtime", "org.jetbrains.skiko", "skiko-js-wasm-runtime").versionRef("skiko")
|
|
}
|
|
}
|
|
}
|
|
|
|
rootProject.name = "SkiaWebSample"
|
|
|
|
if (extra.properties.getOrDefault("skiko.composite.build", "") == "1") {
|
|
includeBuild("../../skiko") {
|
|
dependencySubstitution {
|
|
substitute(module("org.jetbrains.skiko:skiko")).using(project(":"))
|
|
}
|
|
}
|
|
}
|